9 N=100:GT=30
10 GOSUB877
15 POKE53280,2:POKE53281,1:PRINT"[147][154] "
17 V=54296:W=54276:A=54277:H=54273:L=54272:S=54278
20 DIM LE$(10),MI$(15),DI$(10),WU(N),WD$(N),AL$(27)
25 FORI=1TON:READWD$(I):WU(I)=0:NEXT
26 FORI=1TO27:READAL$(I):NEXT
28 GOSUB503
30 RN=INT(N*RND(1))+1
35 IFWU(RN)=1THEN110
40 WU(RN)=1
50 LN=LEN(WD$(RN))
55 FORI=1TOLN:GN$=MID$(WD$(RN),I,1):LE$(I)=GN$:NEXT
80 PRINT"[147]";TAB(13);"GUESS THIS WORD"
85 V1=1205-LN:V2=1285-LN
90 FORI=1TOLN:POKEV1,32:POKEV2,67:POKEV1+L,0:POKEV2+L,0:V1=V1+2:V2=V2+2:NEXT
102 PRINT"ENTER YOUR GUESS "
104 PRINT"LETTERS GUESSED SO FAR:"
106 IT=TI/60
107 TL=TI:TV=TL-60:TU=GT*60
108 GETGS$:IFGS$<>""THEN112
109 GOSUB310:IFTU=0THENGS$=CHR$(45):GOTO115
110 IFGS$=""THEN108
112 IFLEN(GS$)>1THEN108
113 IFASC(GS$)<65ORASC(GS$)>90THEN108
115 GU=GU+1
120 MI$(GU)=GS$
125 FORI=1TOLN
130 IFLE$(I)=DI$(I)THEN145
140 IFGS$=LE$(I)THENDI$(I)=GS$:GOSUB610
145 NEXTI
160 FORJ=1TO27
170 IFMI$(GU)=AL$(J)THEN177
173 NEXTJ
177 V3=1525-LN-5+GU*2-2
178 IFJ=27THENJ=45
180 POKEV3,J:POKEV3+L,0
185 GL=0:GL=LN+5-GU
190 PRINT"GUESSES LEFT:        [157][157][157][157][157][157]";GL
195 AG=1
200 FORI=1TOLN:IFDI$(I)<>LE$(I)THENAG=0
202 NEXTI
204 IFAG=0ANDGL>0THEN107
206 ET=TI/60:FT=INT(ET-IT):TM=INT(FT/60):TS=FT-(TM*60)
208 BA$=STR$(TS):SA$=MID$(BA$,2,2)
210 IFTS<10THENSA$="0"+MID$(BA$,2,1)
214 PRINT"";TAB(20);"GUESS TIME";TM;CHR$(58);SA$
215 IFGL=0ANDAG=0THENGOSUB705
220 IFAG=1THENGOSUB810
225 PRINT"[144]F3 TO QUIT"
230 PRINT"F5 TO GO TO A DIFFERENT WORD[154]"
235 GETAC$:IFAC$=""THEN235
240 IFAC$="[135]"THEN28
245 IFAC$="[134]"THEN PRINT"[147]":END
250 GOTO235
310 TV=TV+60
320 TM=TI-TV
330 IFTM<60THEN320
340 TU=(GT*60-TV+TL)/60
350 B$=STR$(TU)
360 S$=MID$(B$,2,2)
370 IFTU<10THENS$="0"+MID$(B$,2,1)
380 PRINT"";TAB(24);"TIME : ";S$
390 RETURN
503 SP$=" "
505 FORI=1TO10:LE$(I)=SP$:MI$(I)=SP$:DI$(I)=SP$:PK(I)=32:PM(I)=32:NEXT
510 FORI=11TO15:MI$(I)=SP$:NEXT
530 GU=0
540 RETURN
610 FORJ=1TO26
620 IFDI$(I)=AL$(J)THEN625
623 NEXTJ
625 V1=1205-LN+I*2-2
630 POKEV1,J:POKEVI+L,0
635 POKEV,15:POKEW,33:POKEA,32:POKES,240
640 FORT=1TO10:POKEH,68:POKEL,149:NEXT
645 POKEH,0:POKEL,0:POKEW,0
650 FORT=1TO150:NEXT
655 RETURN
705 PRINT"        SORRY, YOU MISSED THE WORD"
710 PRINT"        IT WAS ";WD$(RN)
715 POKEV,15:POKEW,33:POKEA,32:POKES,240
720 FORT=1TO200:POKEH,6:POKEL,16:NEXT
725 POKEH,0:POKEL,0:POKEW,0
730 RETURN
810 PRINT"        *** CONGRATULATIONS ***"
815 POKEV,15:POKEW,33:POKEA,32:POKES,240
820 FORT=1TO25:POKEH,68:POKEL,149:NEXT
825 POKEH,0:POKEL,0
830 FORT=1TO100:POKEH,68:POKEL,149:NEXT
835 POKEH,0:POKEL,0:POKEW,0
850 RETURN
877 POKE53281,15:POKE53280,10
880 PRINT"[147]          [144]W O R D - G U E S S"
890 PRINT:PRINT:PRINT"          INSTRUCTIONS (Y/N)"
895 GETAB$:IFAB$=""THEN895
897 IFAB$<>"Y"THEN975
905 POKE53281,13:POKE53280,3
910 PRINTCHR$(144);"[147]               WORD-GUESS":PRINT
915 PRINT"   THE OBJECT OF WORD-GUESS IS TO DE-"
920 PRINT"TERMINE THE LETTERS THAT MAKEUP A WORD."
922 PRINT"   THE WORD CAN BE UP TO 10 CHARACTERS"
924 PRINT"LONG.  YOU HAVE 5 MORE GUESSES THAN THE"
926 PRINT"LENGTH OF THE WORD TO DETERMINE ALL THE"
928 PRINT"LETTERS."
932 PRINT"   YOU HAVE";GT;"SECONDS TO MAKE A GUESS."
934 PRINT"IF THE LETTER IS IN THE WORD, IT WILL"
936 PRINT"SHOW IN ITS PROPER SLOT. ALL LETTERS"
938 PRINT"USED WILL BE DISPLAYED FOR REFERENCE."
940 PRINT"   MULTIPLE OCCURENCES OF THE SAME"
942 PRINT"LETTER WILL BE SHOWN IN ALL APPROPRIATE"
944 PRINT"SLOTS.":PRINT
946 PRINT"   AFTER GUESSING A WORD, PRESS:"
948 PRINT"     F3[146] TO QUIT":PRINTTAB(8)"OR"
950 PRINT"     F5[146] TO GUESS ANOTHER WORD"
952 PRINT:PRINTTAB(15);"GOOD LUCK!"
954 PRINTTAB(8);"PRESS ANY KEY TO START"
956 GETAD$:IFAD$=""THEN956
975 RETURN
1000 DATA DEGREE,DIVISION,SCROD,NAIVE,THINKER
1005 DATA WATER,LIGHT,REGIME,REVAMP,HYMN
1010 DATA REGENCY,SYMPATHY,COUPON,PLANT,SPOTLIGHT
1015 DATA EXPRESS,AARDVARK,RUBBER,EMINENCE,BOOMERANG
1020 DATA POETIC,EARTHQUAKE,MAIL,PARALYZE,HEAT
1025 DATA LAPSE,NITROGEN,GLASS,IDIOT,MEMORY
1030 DATA FLOWER,COMPUTER,LANDMARK,MESSAGE,CLARITY
1035 DATA AMAZING,HARMONY,GALLON,JELLYFISH,FLAME
1040 DATA ENVIOUS,DOORBELL,DESTINY,DAISY,CORSAGE
1045 DATA CANARY,BOYCOTT,OFFER,BENEFICIAL,ARMADILLO
1050 DATA ANGELIC,MONTH,BALMY,MARGARINE,LODGE
1055 DATA ORIGINAL,OXYGEN,SKIING,PLASMA,PREMATURE
1060 DATA SPECIAL,REGARD,REFUGEE,SHAKE,WATERCRESS
1065 DATA SALOON,WASHABLE,WHATEVER,YOLK,WINDOW
1070 DATA ACTION,ZENITH,YELLOW,TRICYCLE,YAM
1075 DATA FETCH,PRICE,CHEMICAL,DOWNWIND,HIBERNATE
1080 DATA COUNTERACT,CLOVERLEAF,EARTHQUAKE,FLEXIBLE,QUEEN
1085 DATA PRECEDENT,ORANGE,CONSTRUCT,UNICORN,IMPORTANT
1090 DATA MEDALIST,YOURSELF,NOVICE,GEOGRAPHY,EXPENSIVE
1100 DATA MONITOR,HEADACHE,TELEVISION,TAX,LANGUAGE
2000 DATA A,B,C,D,E,F,G,H,I,J,K,L,M
2010 DATA N,O,P,Q,R,S,T,U,V,W,X,Y,Z,-